АРХИВ СТАТЕЙ ЖУРНАЛА «МОЙ КОМПЬЮТЕР» ЗА 2002 ГОД

Уроки ASP-технологии

Все журналы \ Номер 20/191 `2002 от 13.05.2002 \ Уроки ASP-технологии

Объекты доступа к данным.

Экскурс по технологии ASP будет, конечно, неполным, если мы проигнорируем уровень данных при написании сценариев. Поэтому сегодня мы рассмотрим объекты доступа к данным, которые предоставляет разработчикам технология ADO (ActiveX Data Objects). Итак, что же такое ADO? Всеми любимая (а может, и нет () корпорация :-)Microsoft разработала (и всячески продвигает на рынке IT) так называемую концепцию универсального доступа к данным UDO (Universal Data Access), которая позволяет посредством поставщиков услуг OLE DB (Object Linking and Embedding Database) подключаться к любым базам данных, лишь бы для них был установлен соответствующий драйвер. Однако есть одна деталь: технология OLE DB доступна лишь разработчикам, использующим DB (Object Linking and Embedding Database) подключаться к любым базам данных, лишь бы для них был установлен соответствующий драйвер. Однако есть одна деталь: технология OLE C++. Чтобы как-то исправить этот недостаток, Microsoft и выдумала ActiveX Data Objects, которые предоставляют программистам средства доступа к OLE DB. Упрощенное расположение этих технологий по отношению друг к другу, к технологии ASP и к языкам программирования Visual Basic и Visual C++ представлено на Рис. 1.

Давайте рассмотрим подключение к базе данных в ASP-сценарии. Для этого используется объект Connection. Создадим базу данных формата Access, назовем ее orders.mdb. В ней сделаем две классические таблицы: Orders (табл. 2) и Products (табл. 4). В таблице Orders создадим и заполним следующие поля (табл. 1).

После этого создайте таблицу Products, со следующими полями (табл. 3).

Заполните ее таким вот образом (табл. 4).

После этого измените «Схему данных» так это показано на Рис. 2.

Теперь создайте файл dbtest.asp. В него запишите следующий код:

<%@ language=VBScript %>
<% Option Explicit %>

<%
Dim objConn
Dim objRecordset
Dim objField
Dim strSql
Dim strConn

Dim mypath
Dim mypath2
Dim strDBName1
Dim strDBName

myPath=Request.ServerVariables("PATH_TRANSLATED")
MyPath2=InstrRev(myPath,"\")
strDBName1=left(MyPath,MyPath2)
strDBName=strDBName1 & "\"

strConn = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" _
& strDBName & "orders.mdb"

set objConn = Server.CreateObject("ADODB.Connection")
set objRecordset = Server.CreateObject("ADODB.Recordset")

objConn.Mode = adModeReadWrite
objConn.ConnectionString = strConn

objConn.Open

strSql = "SELECT Orders.First_Name,Orders.Last_Name," & _
"Products.Name_Of_Product " & _
"FROM Products INNER JOIN Orders ON Products.Product_ID = " & _
"Orders.Product_ID " & _
"WHERE Orders.Product_ID=8"

set objRecordset = objConn.Execute(strSql)

Response.Write "<table border='1' align='center'>"
Response.Write "<tr>"

for each objField in objRecordset.Fields
	Response.Write "<td>" & objField.Name & "</td>" 
next

Response.Write "</tr>"

do while not objRecordset.EOF
	Response.Write "<tr>"

for each objField in objRecordset.Fields
			Response.Write "<td>" & objField.Value & "</td>" 
		next

Response.Write "</tr>"
	objRecordset.MoveNext
loop

Response.Write "</table>"

objRecordset.Close
objConn.Close

set objRecordset = Nothing
set objConn = Nothing

Давайте разберемся, что же делает этот сценарий. В первой строке

мы устанавливаем язык сценария. В следующей строке дается обязательное объявление переменных. Далее подключается внешний файл adovbs.inc, который необходимо скопировать в подкаталог includes, находящийся в одной папке с файлом dbtest.asp, из каталога диск:\Program Files\Common Files\System\ADO\. Файл adovbs.inc нужно подключить, так как в последующем коде мы используем константу adModeReadWrite, которая подсоединяет базу данных в режиме чтение/запись. В последующих девяти строках объявляются используемые в дальнейшем переменные, а затем с помощью строковых функций формируется нужный путь к базе данных. После этого переменной strConn присваивается так называемая строка подключения, которая используется для выбора нужного драйвера доступа к базе данных (которая также указывается в этой строке).

В следующих двух строках создаются объекты Connection и Recordset. Далее устанавливается режим доступа к нашей базе данных и свойству ConnectionString объекта Connection присваивается строка strConn, в которой уже указаны все параметры подключения к источнику данных. И теперь, наконец-то, с помощью метода Open, устанавливается непосредственно соединение с базой данных. Теперь мы можем использовать это соединение для операций над данными: переменной strSql присваивается текст SQL-запроса, который в дальнейшем используется для выборки из базы данных всех клиентов, заказавших продукт под номером 8 (в таблице Orders это будет машина Aldan, которая использовалась для решения различных магических задач в произведении братьев Стругацких «Понедельник начинается в субботу»). Далее объекту objRecordset присваивается результат выполнения этого запроса, браузеру же посылаются строки:

После этого в цикле for each objField in objRecordset.Fields … Next формируются и посылаются браузеру заголовки столбцов из выборки, которую мы сделали раньше. Затем посылается текст.

Теперь в цикле do while not objRecordset.EOF … loop мы посылаем записи из нашей выборки, сформированные в виде таблицы. Как только эти данные были посланы, браузер получает тэг окончания таблицы (</table>). Следующим шагом мы закрываем открытые соединения и уничтожаем их. Это делается для того, чтобы они не занимали место в оперативной памяти компьютера после завершения сценприя.

В итоге браузер получает HTML-таблицу с информацией из нашей базы данных, причем пользователь не видит ни ее реальной структуры, ни физического расположения на диске.

(Продолжение следует)

Рекомендуем ещё прочитать:

Borland Kylix 2. (№9/180 `2002) Нет Автора
Мысли о Паскале. (№10/181 `2002) Владислав Демьянишин
Мысли о Паскале. (№12/183 `2002) Владислав Демьянишин
Мышление в стиле Visual Basic. (№20/191 `2002) Андрей Гончаров
Мысли о Паскале. (№34/205 `2002) Владислав Демьянишин
Интерфейс в XPерементальном стиле. (№37/208 `2002) Вячеслав Джура
7 правил успеха программы. (№43/214 `2002) Петр 'roxton' Семилетов
Ломать не строить. (№44/215 `2002) Игорь Павлов
Вездесущий EXE. (№52/223 `2002) Руслан Ризванов

Предыдущая статья Назад К списку журналов Следующая статья